Display rows vertically

ALTER procedure [dbo].[vselect]
@table_name varchar(max),
@where_clause varchar(max)=''
AS
    -- Display table row(s) vertically, in alphabetic order.
    -- Usage: vselect 'tablename' [,'where ~']
set nocount on

declare @col_names varchar(max)
declare @variants varchar(max)
declare @sql varchar(max)
set @col_names=''
set @variants = ''

select @col_names = @col_names + c.column_name + ',',
    @variants = @variants + 'CONVERT(SQL_VARIANT, '+c.column_name + ') AS '+c.column_name+','
from 
    information_schema.columns c
where table_name = @table_name
 and table_schema = 'dbo'
 and data_type not in ('text','ntext','image','timestamp')
order by c.column_name

set @col_names = left(@col_names,len(@col_names)-1)
set @variants = left(@variants,len(@variants)-1)

set @sql = 
'
SELECT 
 TBLPIVOT.Column_Name,
 TBLPIVOT.Value
FROM 
(SELECT ' + @variants +
' FROM ' + @table_name + ' ' +
@where_clause + ') x UNPIVOT (VALUE FOR Column_Name IN ('
+ @col_names + ')) AS TBLPIVOT'

exec(@sql)