disable/enable indexes for table

if object_id('usp_toggle_index') is not null
    drop procedure usp_toggle_index
go

create procedure usp_toggle_index(@objectname sysname, @switch bit = 0, @debug bit = 0, @verbose bit = 1) as
begin
    declare @SQLCmd nvarchar(512)
    declare @action nvarchar(16)
    declare @counter int

    set @counter = 0

    if @switch = 0
        set @action = ' disable;'
    else
        set @action = ' rebuild;'
        
    declare c_toggle_index cursor for
        select    'alter index ' + QUOTENAME(name) + ' on ' + QUOTENAME(@objectname) + @action
        from    sys.indexes
        where    type_desc = 'nonclustered'
        and        is_unique = 0
        and        is_primary_key = 0
        and        is_unique_constraint = 0
        and        is_disabled = @switch
        and        object_id = object_id(@objectname)

    open    c_toggle_index
    
    fetch    next
    from    c_toggle_index 
    into    @SQLCmd

    while @@fetch_status = 0
        begin
            set @counter = @counter + 1
            if @debug = 0
                exec (@SQLCmd)
            else
                print @SQLCmd

            fetch next
            from c_toggle_index 
            into @SQLCmd
        end

    close c_toggle_index
    deallocate c_toggle_index

    if @verbose = 1
        print '- processed ' + cast(@Counter as varchar) + ' indexes for table ' + @objectname
end
go